Packages: add kame-editor and dependencies

flake.nix

@@ -133,13 +133,16 @@
         };
         overlays.default = final: prev: {
           kasane-teto-cursor = final.callPackage ./pkgs/kasane-teto-cursor {};
+          kame-editor = final.callPackage ./pkgs/kame-editor {};
+          kame-tools = final.callPackage ./pkgs/kame-tools {};
+          rstmcpp = final.callPackage ./pkgs/rstmcpp {};
         };
         packages = {
           x86_64-linux = with import nixpkgs-unstable-raw {
             system = "x86_64-linux";
             overlays = [self.overlays.default];
           }; {
-            inherit kasane-teto-cursor;
+            inherit kasane-teto-cursor kame-editor kame-tools rstmcpp;
           };
         };
         nixosConfigurations = let

pkgs/kame-editor/default.nix

@@ -0,0 +1,53 @@
+{
+  stdenv,
+  fetchFromGitLab,
+  qt6,
+  portaudio,
+  kame-tools,
+  vgmstream,
+  rstmcpp,
+}:
+stdenv.mkDerivation rec {
+  name = "kame-editor";
+  version = "1.4.1";
+
+  src = fetchFromGitLab {
+    owner = "beelzy";
+    repo = name;
+    # tag = version;
+    rev = "82c9c445644b133b6d0ce3529e65b1a3df83c804";
+    hash = "sha256-V2nMvVIjFRM8++XQ9tkE2OiZzCvdrg0jK69HM+ZIVyA=";
+  };
+
+  postPatch = ''
+    substituteInPlace kame-editor.pro \
+      --replace-fail "/usr/local/bin/" "$out/bin"
+  '';
+
+  buildInputs = [
+    qt6.qtbase
+    portaudio
+    kame-tools
+    vgmstream
+    rstmcpp
+  ];
+
+  dontStrip = true;
+
+  nativeBuildInputs = [
+    qt6.qmake
+    qt6.wrapQtAppsHook
+  ];
+
+  postBuild = ''
+    bash ./buildicons.sh
+  '';
+
+  postInstall = ''
+    mkdir -p $out/share/icons/hicolor
+    mkdir -p $out/share/applications
+
+    cp kame-editor.desktop $out/share/applications
+    cp -r icons/. $out/share/icons/hicolor
+  '';
+}

pkgs/kame-tools/default.nix

@@ -0,0 +1,29 @@
+{
+  stdenv,
+  fetchFromGitLab,
+  zip,
+}:
+stdenv.mkDerivation rec {
+  name = "kame-tools";
+  version = "a1fe47cc";
+
+  src = fetchFromGitLab {
+    owner = "beelzy";
+    repo = name;
+    rev = version;
+    fetchSubmodules = true;
+    hash = "sha256-ETl5f8M4OJPFB7NEq2mVuMm4RhBtAbMzlrvGHD14zXw=";
+  };
+
+  postPatch = ''
+    substituteInPlace buildtools/make_base \
+      --replace-fail "/usr/local/bin" "$out/bin"
+  '';
+
+  installPhase = ''
+    mkdir -p $out/bin
+    cp output/linux-x86_64/* $out/bin/
+  '';
+
+  nativeBuildInputs = [zip];
+}

pkgs/rstmcpp/default.nix

@@ -0,0 +1,21 @@
+{
+  stdenv,
+  fetchFromGitLab,
+}:
+stdenv.mkDerivation rec {
+  name = "rstmcpp";
+  version = "fe8bee01";
+
+  src = fetchFromGitLab {
+    owner = "beelzy";
+    repo = name;
+    rev = version;
+    fetchSubmodules = true;
+    hash = "sha256-T9mxTBj/eykvbBkbmEKTUFldtBp3cJgWAbeu44SwxiM=";
+  };
+
+  installPhase = ''
+    mkdir -p $out/bin
+    cp rstmcpp $out/bin
+  '';
+}